LTW3/data/ltw/functions/state/0/tick5.mcfunction

# 隐藏/显示 骰子房老板的名片
execute as @e[type=piglin,tag=shop_piglin_11,tag=lobby_entity] at @s if entity @a[distance=..5] run data modify entity @s CustomNameVisible set value true
execute as @e[type=piglin,tag=shop_piglin_11,tag=lobby_entity] at @s unless entity @a[distance=..5] run data modify entity @s CustomNameVisible set value false

# 调用节奏方块
function lib:tempo_block/tick5

# TODO: 未完成的重构

## 20s：提示未准备
#execute if score $start_countdown mem matches 80 run tellraw @a[team=watching] [{"text":"","color":"red"},{"text":">> ","bold": true},"你还没有准备, 如果要参加游戏, 请丢出快捷栏最后一格的物品!"]

## 让无状态玩家变为旁观状态
#execute as @a[team=!debug,team=!hub_play,team=!hub_watch] run function ltw:state/0/sp/join_watch

## 给予主大厅进度
#execute as @a at @s if entity @s[x=-1,y=22,z=-29,dx=5,dy=3,dz=3] run advancement grant @s only ltw:parkour/explore1
#execute as @a at @s if entity @s[x=6,y=48,z=-32,dx=4,dy=3,dz=9] run advancement grant @s only ltw:parkour/explore2
#execute as @a at @s if entity @s[x=0,y=28,z=-46,distance=..4] run advancement grant @s only ltw:parkour/explore3


# ————————————————————————————————————————————————————————————————————————————
#  游戏开始倒计时
# ————————————————————————————————————————————————————————————————————————————

# 检查人数
execute store result score #ready_count mem if entity @a[team=hub_play]
execute store result score #total_count mem if entity @a

# 人数足够，开始倒计时
execute if score #ready_count mem matches 3.. if score $start_countdown mem matches 999.. run tellraw @a [{"text":" ❇ ","color":"green"}," 游戏即将开始， 请使用第一格的物品确定自己是否参与！"]
execute if score #ready_count mem matches 3.. if score $start_countdown mem matches 999.. as @a at @s run function lib:sounds/levelup
execute if score #ready_count mem matches 3.. if score $start_countdown mem matches 999.. run scoreboard players set $start_countdown mem 121

# 人数不足，取消倒计时
execute if score #ready_count mem matches ..2 if score $start_countdown mem matches ..999 run tellraw @a [{"text":" ✖ ","color":"red"}," 准备人数不足， 开始倒计时已取消！"]
execute if score #ready_count mem matches ..2 if score $start_countdown mem matches ..999 as @a at @s run function lib:sounds/error
execute if score #ready_count mem matches ..2 if score $start_countdown mem matches ..999 run scoreboard players set $start_countdown mem 9999999

# 20s：提示玩家数量过多
execute if score $start_countdown mem matches 80 if score #ready_count mem matches 9.. run tellraw @a [{"text":" ❇ ","color":"gold"}," 准备人数已超出 8 人的人数上限, 将随机抽取 8 人进行游戏！"]

# 10s：播放倒计时音效
scoreboard players remove $start_countdown mem 1
scoreboard players operation #start_sec mem = $start_countdown mem
scoreboard players operation #start_sec mem /= #4 mem
scoreboard players operation #start_div mem = $start_countdown mem
scoreboard players operation #start_div mem %= #4 mem
execute if score #start_sec mem matches 1..10 if score #start_div mem matches 3 run execute as @a at @s run function lib:sounds/hit2

# 0s：开始游戏
execute if score $start_countdown mem matches 0 run function ltw:state/0/start_game

# 显示信息
execute if score $start_countdown mem matches 1..999 run title @a[team=!debugging] actionbar [{"text":"","color":"green"},{"score":{"name":"#ready_count","objective":"mem"}},"/",{"score":{"name":"#total_count","objective":"mem"}}," 人已准备 | ","将在 ",{"score":{"name":"#start_sec","objective":"mem"}}," 秒后开始游戏"]
execute if score $start_countdown mem matches 999.. run title @a[team=!debugging] actionbar [{"text":"","color":"red"},{"score":{"name":"#ready_count","objective":"mem"}},"/",{"score":{"name":"#total_count","objective":"mem"}}," 人已准备 | 需要 3 人以开始游戏"]