ModLoader.vb 37 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456457458459460461462463464465466467468469470471472473474475476477478479480481482483484485486487488489490491492493494495496497498499500501502503504505506507508509510511512513514515516517518519520521522523524525526527528529530531532533534535536537538539540541542543544545546547548549550551552553554555556557558559560561562563564565566567568569570571572573574575576577578579580581582583584585586587588589590591592593594595596597598599600601602603604605606607608609610611612613614615616617618619620621622623624625626627628629630631632633634635636637638639640641642643644645646647648649650651652653654655656657658659660661662663664665666667668669670671672673674675676677678679680681682683684685686687688689690691692693694695696697698699700701702703704705706707708709710711712713714715716717718719720721722723724725726727728729730731732733734735736737738739740741742743744745746747748749750751752753754755756757758759760761762763764765766767768769770771772773774775776777778779780781782783784785786787788789790791792793794795
  1. Public Module ModLoader
  2. '各类加载器
  3. ''' <summary>
  4. ''' 加载器的统一基类。
  5. ''' </summary>
  6. Public MustInherit Class LoaderBase
  7. Implements ILoadingTrigger
  8. Public ReadOnly Property IsLoader As Boolean = True Implements ILoadingTrigger.IsLoader
  9. '基础属性
  10. ''' <summary>
  11. ''' 加载器的标识编号。
  12. ''' </summary>
  13. Public Uuid As Integer = GetUuid()
  14. ''' <summary>
  15. ''' 加载器的名称。
  16. ''' </summary>
  17. Public Name As String = "未命名任务 " & Uuid & "#"
  18. ''' <summary>
  19. ''' 用于状态改变检测的同步锁。
  20. ''' </summary>
  21. Public ReadOnly LockState As New Object
  22. ''' <summary>
  23. ''' 父加载器。
  24. ''' </summary>
  25. Public Parent As LoaderBase = Nothing
  26. ''' <summary>
  27. ''' 最上级的加载器。
  28. ''' </summary>
  29. Public ReadOnly Property RealParent As LoaderBase
  30. Get
  31. Try
  32. RealParent = Parent
  33. While RealParent IsNot Nothing AndAlso RealParent.Parent IsNot Nothing
  34. RealParent = RealParent.Parent
  35. End While
  36. Catch ex As Exception
  37. Logger.Error(ex, $"获取父加载器失败({Name})")
  38. Return Nothing
  39. End Try
  40. End Get
  41. End Property
  42. Public Overridable Sub InitParent(Parent As LoaderBase)
  43. Me.Parent = Parent
  44. End Sub
  45. '事件
  46. ''' <summary>
  47. ''' 当状态改变时,在工作线程触发代码。在添加事件后,必须将 HasOnStateChangedThread 设为 True。
  48. ''' </summary>
  49. Public Event OnStateChangedThread(Loader As LoaderBase, NewState As LoadState, OldState As LoadState)
  50. Public HasOnStateChangedThread As Boolean = False
  51. ''' <summary>
  52. ''' 当状态改变时,在 UI 线程触发代码。
  53. ''' </summary>
  54. Public Event OnStateChangedUi(Loader As LoaderBase, NewState As LoadState, OldState As LoadState)
  55. ''' <summary>
  56. ''' 简易的在 UI 线程添加触发事件的方式。主要用于在新建 Loader 时直接使用 With 绑定事件,以及进行老代码兼容。
  57. ''' </summary>
  58. Public WriteOnly Property OnStateChanged As Action(Of LoaderBase)
  59. Set(value As Action(Of LoaderBase))
  60. AddHandler OnStateChangedUi, Sub(Loader As LoaderBase, NewState As LoadState, OldState As LoadState) value(Loader)
  61. End Set
  62. End Property
  63. ''' <summary>
  64. ''' 在加载器目标事件执行完成,加载器状态即将变为 Finish 时调用。可以视为扩展加载器目标事件。
  65. ''' </summary>
  66. Public Event PreviewFinish(Loader As LoaderBase)
  67. Protected Sub RaisePreviewFinish()
  68. RaiseEvent PreviewFinish(Me)
  69. End Sub
  70. '状态监控
  71. ''' <summary>
  72. ''' 加载器的状态。
  73. ''' </summary>
  74. Public Property State As LoadState
  75. Get
  76. Return _State
  77. End Get
  78. Set(value As LoadState)
  79. If _State = value Then Return
  80. Dim OldState = _State
  81. If value = LoadState.Finished AndAlso Settings.Get(Of Boolean)("SystemDebugDelay") Then Thread.Sleep(RandomInteger(100, 2000))
  82. _State = value
  83. If value = LoadState.Canceled Then CancellationTokenSource?.Cancel()
  84. Logger.Log($"加载器 {[GetType].Name} {Name} 状态改变:{value}", If(value = LoadState.Failed, LogLevel.Error, LogLevel.Info))
  85. '实现 ILoadingTrigger 接口与 OnStateChanged 回调
  86. RunInUi(
  87. Sub()
  88. Select Case value
  89. Case LoadState.Loading
  90. LoadingState = MyLoading.MyLoadingState.Run
  91. Case LoadState.Failed
  92. LoadingState = MyLoading.MyLoadingState.Error
  93. Case Else
  94. LoadingState = MyLoading.MyLoadingState.Stop
  95. End Select
  96. RaiseEvent OnStateChangedUi(Me, value, OldState)
  97. End Sub)
  98. If HasOnStateChangedThread Then RunInThread(Sub() RaiseEvent OnStateChangedThread(Me, value, OldState))
  99. End Set
  100. End Property
  101. Private _State As LoadState = LoadState.Waiting
  102. Public Property LoadingState As MyLoading.MyLoadingState Implements ILoadingTrigger.LoadingState
  103. Get
  104. Return _LoadingState
  105. End Get
  106. Set(value As MyLoading.MyLoadingState)
  107. If _LoadingState = value Then Return
  108. Dim OldState = _LoadingState
  109. _LoadingState = value
  110. RaiseEvent LoadingStateChanged(value, OldState)
  111. End Set
  112. End Property
  113. Private _LoadingState As MyLoading.MyLoadingState = MyLoading.MyLoadingState.Stop
  114. Public Event LoadingStateChanged(NewState As MyLoading.MyLoadingState, OldState As MyLoading.MyLoadingState) Implements ILoadingTrigger.LoadingStateChanged
  115. ''' <summary>
  116. ''' 若加载器出错,可提供给外部参考的异常。
  117. ''' </summary>
  118. Public Property [Error] As Exception = Nothing
  119. ''' <summary>
  120. ''' 使用 LoaderCombo 加载时,该任务是否会阻碍后续任务的进行。
  121. ''' </summary>
  122. Public Block As Boolean = True
  123. ''' <summary>
  124. ''' 该加载器是否显示在列表中。
  125. ''' </summary>
  126. Public Show As Boolean = True
  127. ''' <summary>
  128. ''' 当前加载器是否由 IsForceRestart 强制调起。
  129. ''' 这个属性自身不会干任何事,而是提供给加载器执行的函数,使得加载器调用另一个加载器时,可以继承强制重启属性。
  130. ''' </summary>
  131. Public IsForceRestarting As Boolean = False
  132. '进度监控
  133. ''' <summary>
  134. ''' 加载器的执行进度,为 0 至 1 的小数。
  135. ''' </summary>
  136. Public Overridable Property Progress As Double
  137. Get
  138. Select Case State
  139. Case LoadState.Waiting
  140. Return 0
  141. Case LoadState.Loading
  142. Return If(_Progress = -1, 0, _Progress)
  143. Case Else
  144. Return 1
  145. End Select
  146. End Get
  147. Set(value As Double)
  148. If _Progress = value Then Return
  149. Dim OldValue = _Progress
  150. _Progress = value
  151. RaiseEvent ProgressChanged(value, OldValue)
  152. End Set
  153. End Property
  154. Private _Progress As Double = -1
  155. Public Event ProgressChanged(NewProgress As Double, OldProgress As Double) Implements ILoadingTrigger.ProgressChanged
  156. ''' <summary>
  157. ''' 创建一个 ProgressProvider,在其进度改变时,并将其进度单向映射到此加载器上。
  158. ''' 这是 Loader 对新框架的兼容层。
  159. ''' </summary>
  160. Public Function CreateSyncProgressProvider(Optional FromPercentage As Double = 0, Optional ToPercentage As Double = 1) As ProgressProvider
  161. Dim Provider As New ProgressProvider
  162. AddHandler Provider.ProgressChanged,
  163. Sub(ChangedProgress)
  164. Dim RawProgress = Provider.GetRaw()
  165. Progress = FromPercentage + (RawProgress.actual + RawProgress.skiped) * (ToPercentage - FromPercentage)
  166. End Sub
  167. Return Provider
  168. End Function
  169. ''' <summary>
  170. ''' 计算总进度时的权重。它应该为预计时间(秒)。
  171. ''' </summary>
  172. Public Property ProgressWeight As Double = 1
  173. '状态变化
  174. Public MustOverride Sub Start(Optional Input As Object = Nothing, Optional IsForceRestart As Boolean = False)
  175. Public MustOverride Sub Cancel()
  176. Public MustOverride Sub Failed(Ex As Exception)
  177. Private CancellationTokenSource As CancellationTokenSource
  178. ''' <summary>
  179. ''' 创建一个随此加载器取消的取消令牌;令牌取消时也会调用此加载器的 Cancel。
  180. ''' 这是 Loader 对新框架的兼容层。
  181. ''' </summary>
  182. Public Function CreateCancellationToken() As CancellationToken
  183. SyncLock LockState
  184. If CancellationTokenSource Is Nothing OrElse CancellationTokenSource.IsCancellationRequested Then
  185. CancellationTokenSource = New CancellationTokenSource
  186. CancellationTokenSource.Token.Register(AddressOf Cancel)
  187. End If
  188. If State = LoadState.Canceled Then CancellationTokenSource.Cancel()
  189. Return CancellationTokenSource.Token
  190. End SyncLock
  191. End Function
  192. '等待结束
  193. Public Const WaitForExitTimeoutMessage As String = "等待加载器执行超时。"
  194. ''' <summary>
  195. ''' 无限期地等待加载器完成,直到结束或抛出异常。若加载器尚未开始,则会开始执行。
  196. ''' </summary>
  197. Public Sub WaitForExit(Optional Input As Object = Nothing, Optional LoaderToSyncProgress As LoaderBase = Nothing, Optional IsForceRestart As Boolean = False,
  198. Optional c As CancellationToken = Nothing, Optional p As ProgressProvider = Nothing)
  199. Start(Input, IsForceRestart)
  200. Do While State = LoadState.Loading
  201. If LoaderToSyncProgress IsNot Nothing Then LoaderToSyncProgress.Progress = Progress
  202. p?.Set(Progress)
  203. c.ThrowIfCancellationRequested()
  204. Thread.Sleep(10)
  205. Loop
  206. If State = LoadState.Finished Then
  207. Return
  208. ElseIf State = LoadState.Canceled Then
  209. Throw New OperationCanceledException("加载器执行已中断")
  210. ElseIf IsNothing([Error]) Then
  211. Throw New Exception("未知错误!")
  212. Else
  213. Throw New Exception([Error].Message, [Error]) '保留调用堆栈,同时不影响信息输出与单元测试
  214. End If
  215. End Sub
  216. ''' <summary>
  217. ''' 等待加载器完成,直到结束、抛出异常或超时。若加载器尚未开始,则会开始执行。
  218. ''' </summary>
  219. ''' <param name="Timeout">等待的超时时间,以毫秒为单位。</param>
  220. ''' <param name="TimeoutMessage">若执行超时,将会抛出的异常信息。</param>
  221. Public Sub WaitForExitTime(Timeout As Integer, Optional Input As Object = Nothing, Optional TimeoutMessage As String = WaitForExitTimeoutMessage, Optional LoaderToSyncProgress As Object = Nothing, Optional IsForceRestart As Boolean = False)
  222. Start(Input, IsForceRestart)
  223. Do While State = LoadState.Loading
  224. If LoaderToSyncProgress IsNot Nothing Then LoaderToSyncProgress.Progress = Progress
  225. Thread.Sleep(10)
  226. Timeout -= 10
  227. If Timeout < 0 Then Throw New TimeoutException(TimeoutMessage)
  228. Loop
  229. If State = LoadState.Finished Then
  230. Return
  231. ElseIf State = LoadState.Canceled Then
  232. Throw New OperationCanceledException("加载器执行已中断")
  233. ElseIf IsNothing([Error]) Then
  234. Throw New Exception("未知错误!")
  235. Else
  236. Throw [Error]
  237. End If
  238. End Sub
  239. '相同重载
  240. Public Overrides Function Equals(obj As Object) As Boolean
  241. Dim base = TryCast(obj, LoaderBase)
  242. Return base IsNot Nothing AndAlso Uuid = base.Uuid
  243. End Function
  244. End Class
  245. ''' <summary>
  246. ''' 用于异步执行并监控单一函数的加载器。
  247. ''' </summary>
  248. Public Class LoaderTask(Of TIn, TOut)
  249. Inherits LoaderBase
  250. '线程设定
  251. Protected Friend ThreadPriority As ThreadPriority
  252. '执行事件
  253. Protected Friend LoadDelegate As Action(Of LoaderTask(Of TIn, TOut))
  254. Protected Friend InputDelegate As Func(Of Object)
  255. '状态指示
  256. ''' <summary>
  257. ''' 当前执行线程是否应当中断。只应用在加载器的工作线程中判断,不可跨线程调用。
  258. ''' </summary>
  259. Public ReadOnly Property IsCanceled As Boolean
  260. Get
  261. Return IsCanceledWithThread(Thread.CurrentThread)
  262. End Get
  263. End Property
  264. ''' <summary>
  265. ''' 当前执行线程是否应当中断。需要手动提供加载器线程,用于需要跨线程检查的情况。
  266. ''' </summary>
  267. Public Function IsCanceledWithThread(Thread As Thread) As Boolean
  268. Return LastRunningThread Is Nothing OrElse Not ReferenceEquals(Thread, LastRunningThread) OrElse State = LoadState.Canceled
  269. End Function
  270. ''' <summary>
  271. ''' 在输入相同时使用原有结果的超时,单位为毫秒。
  272. ''' </summary>
  273. Public ReloadTimeout As Integer = -1
  274. ''' <summary>
  275. ''' 上次完成加载时的时间。
  276. ''' </summary>
  277. Public LastFinishedTime As Long = 0
  278. ''' <summary>
  279. ''' 最后一次运行加载器的线程。可能为 Nothing,或线程已结束。
  280. ''' </summary>
  281. Public LastRunningThread As Thread = Nothing
  282. '输入输出
  283. Public Input As TIn = Nothing
  284. Public Output As TOut = Nothing
  285. '获取输入
  286. Public Function StartGetInput(Optional Input As TIn = Nothing, Optional InputDelegate As Func(Of TIn) = Nothing) As TIn 'InputDelegate 参数存在匿名调用
  287. If InputDelegate Is Nothing Then InputDelegate = Me.InputDelegate
  288. Dim NewInput As TIn = Nothing '若 InputType 不能为 Nothing,则会导致 Input Is Nothing 永远失败,因此需要额外判断
  289. If (Input Is Nothing OrElse (NewInput IsNot Nothing AndAlso Input.Equals(NewInput))) AndAlso InputDelegate IsNot Nothing Then
  290. RunInUiWait(Sub() Input = InputDelegate())
  291. End If
  292. Return Input
  293. End Function
  294. '代码执行
  295. Public Function ShouldStart(ByRef Input As TIn, Optional IsForceRestart As Boolean = False, Optional IgnoreReloadTimeout As Boolean = False) As Boolean
  296. '获取输入
  297. Try
  298. Input = StartGetInput(Input)
  299. Catch ex As Exception When ex.IsCanceled
  300. '线程因获取输入期间加载器被重启而中断,此时输入无效,直接忽略,不应视为加载失败
  301. Logger.Trace(ex, $"加载输入获取因取消而中断({Name})")
  302. Return False
  303. Catch ex As Exception
  304. Logger.Error(ex, $"加载输入获取失败({Name})", LogBehavior.Toast)
  305. [Error] = ex
  306. SyncLock LockState
  307. State = LoadState.Failed
  308. End SyncLock
  309. End Try
  310. '检验输入以确定情况
  311. If IsForceRestart Then Return True '强制要求重启
  312. If ((Input Is Nothing) <> (Me.Input Is Nothing)) OrElse (Input IsNot Nothing AndAlso Not Input.Equals(Me.Input)) Then Return True '输入不同
  313. If (State = LoadState.Loading OrElse State = LoadState.Finished) AndAlso '正在加载或已结束…
  314. (IgnoreReloadTimeout OrElse ReloadTimeout = -1 OrElse
  315. LastFinishedTime = 0 OrElse GetTimeMs() - LastFinishedTime < ReloadTimeout) Then '…且没有超时…
  316. Return False '…则不重试
  317. Else
  318. Return True '否则需要重启
  319. End If
  320. End Function
  321. Public Overrides Sub Start(Optional Input As Object = Nothing, Optional IsForceRestart As Boolean = False)
  322. '确认是否开始加载
  323. If ShouldStart(Input, IsForceRestart) Then
  324. '输入不同或失败,开始加载
  325. If State = LoadState.Loading Then TriggerThreadInterrupt()
  326. Me.Input = Input
  327. SyncLock LockState
  328. State = LoadState.Loading
  329. Progress = -1
  330. End SyncLock
  331. Else
  332. Return
  333. End If
  334. LastRunningThread = New Thread(
  335. Sub()
  336. Try
  337. IsForceRestarting = IsForceRestart
  338. Logger.Trace(Function() $"加载线程 {Name} 已{If(IsForceRestarting, "强制", "")}启动")
  339. LoadDelegate(Me)
  340. If IsCanceled Then
  341. Logger.Warn($"加载线程 {Name} 已中断但线程正常运行至结束,输出被弃用(最新线程:{If(LastRunningThread Is Nothing, -1, LastRunningThread.ManagedThreadId)})")
  342. Return
  343. End If
  344. Logger.Trace(Function() $"加载线程 {Name} 已完成")
  345. RaisePreviewFinish()
  346. State = LoadState.Finished
  347. LastFinishedTime = GetTimeMs() '未中断,本次输出有效
  348. Catch ex As Exception
  349. If ex.IsCanceled Then
  350. '如果线程是因为判断到 IsCanceled 而提前中止,则代表已有新线程被重启,此时不应当改为 Canceled
  351. '如果线程是在没有 IsCanceled 时手动引发了取消异常,则代表没有重启线程,这通常代表用户手动取消,应当改为 Canceled
  352. Logger.Trace(ex, $"加载线程 {Name} 已取消,当前已完成 {Math.Round(Progress * 100)}%")
  353. If Not IsCanceled Then State = LoadState.Canceled
  354. Else
  355. Failed(ex)
  356. End If
  357. End Try
  358. End Sub) With {.Name = "L/" & Name, .Priority = ThreadPriority}
  359. Try
  360. LastRunningThread.Start() '不能使用 RunInNewThread,否则在函数返回前线程就会运行完,导致误判 IsCanceled
  361. Catch ex As ThreadStateException '若遇到偶发的 “线程正在运行或被终止”,则等待后重试
  362. Thread.Sleep(500)
  363. LastRunningThread.Start()
  364. End Try
  365. End Sub
  366. Public Overrides Sub Failed(ex As Exception)
  367. [Error] = ex
  368. SyncLock LockState
  369. If IsCanceled OrElse State >= LoadState.Finished Then Return
  370. State = LoadState.Failed
  371. End SyncLock
  372. Logger.Warn(ex, $"加载线程 {Name} 出错,已完成 {Math.Round(Progress * 100)}%")
  373. TriggerThreadInterrupt()
  374. End Sub
  375. Public Overrides Sub Cancel()
  376. SyncLock LockState
  377. If State <> LoadState.Loading Then Return
  378. State = LoadState.Canceled
  379. End SyncLock
  380. TriggerThreadInterrupt()
  381. End Sub
  382. Private Sub TriggerThreadInterrupt()
  383. If LastRunningThread Is Nothing Then Return
  384. If LastRunningThread.IsAlive Then
  385. LastRunningThread.Interrupt()
  386. Logger.Trace(Function() $"加载线程 {Name} 已中断")
  387. End If
  388. LastRunningThread = Nothing
  389. End Sub
  390. Public Sub New()
  391. '仅仅是为了避免一些智障报错(继承类必须重写 New 的情况)
  392. End Sub
  393. Public Sub New(Name As String, LoadDelegate As Action(Of LoaderTask(Of TIn, TOut)), Optional InputDelegate As Func(Of TIn) = Nothing, Optional Priority As ThreadPriority = ThreadPriority.Normal)
  394. Me.Name = Name
  395. Me.LoadDelegate = LoadDelegate
  396. Me.InputDelegate = InputDelegate
  397. ThreadPriority = Priority
  398. End Sub
  399. End Class
  400. ''' <summary>
  401. ''' 新 Worker 对老 Loader 的兼容包装类。
  402. ''' </summary>
  403. Public Class LoaderWorker
  404. Inherits LoaderBase
  405. Public WithEvents Worker As IWorker
  406. Public Sub New(Name As String, Worker As IWorker)
  407. Me.Name = Name
  408. Me.Worker = Worker
  409. AddHandler Worker.Progress.ProgressChanged, Sub(Raw) Progress = Raw.actual + Raw.skiped
  410. End Sub
  411. Public Overrides Sub Start(Optional Input As Object = Nothing, Optional IsForceRestart As Boolean = False)
  412. SyncLock LockState
  413. State = LoadState.Loading
  414. End SyncLock
  415. Logger.Trace(Function() $"Worker {Name} 已启动")
  416. IsForceRestarting = IsForceRestart
  417. Worker.Start()
  418. End Sub
  419. Private Sub Worker_Succeeded() Handles Worker.Succeeded
  420. Logger.Trace(Function() $"Worker {Name} 已完成")
  421. RaisePreviewFinish()
  422. SyncLock LockState
  423. State = LoadState.Finished
  424. End SyncLock
  425. End Sub
  426. Public Overrides Sub Cancel() Handles Worker.Canceled
  427. SyncLock LockState
  428. If State <> LoadState.Loading Then Return
  429. State = LoadState.Canceled
  430. End SyncLock
  431. Logger.Trace(Function() $"Worker {Name} 已取消,当前已完成 {Math.Round(Progress * 100)}%")
  432. Worker.Cancel()
  433. End Sub
  434. Public Overrides Sub Failed(Ex As Exception) Handles Worker.Failed
  435. SyncLock LockState
  436. If State >= LoadState.Finished Then Return
  437. State = LoadState.Failed
  438. End SyncLock
  439. Logger.Warn(Ex, $"Worker {Name} 出错,已完成 {Math.Round(Progress * 100)}%")
  440. [Error] = Ex
  441. Worker.Cancel()
  442. End Sub
  443. End Class
  444. ''' <summary>
  445. ''' 支持多个加载器连续运作的复合加载器。
  446. ''' </summary>
  447. Public Class LoaderCombo(Of InputType)
  448. Inherits LoaderBase
  449. Public Overrides Property Progress() As Double
  450. Get
  451. Select Case State
  452. Case LoadState.Waiting
  453. Return 0
  454. Case LoadState.Loading
  455. Dim Total As Double = 0, Finished As Double = 0
  456. For Each Loader In Loaders
  457. Total += Loader.ProgressWeight
  458. Finished += Loader.ProgressWeight * Loader.Progress
  459. Next
  460. If Total = 0 Then Return 0
  461. Return Finished / Total
  462. Case Else
  463. Return 1
  464. End Select
  465. End Get
  466. Set(value As Double)
  467. Throw New Exception("多重加载器不支持设置进度")
  468. End Set
  469. End Property
  470. Public Loaders As New List(Of LoaderBase)
  471. Public Input As InputType
  472. Public Sub New(Name As String, Loaders As IEnumerable(Of LoaderBase))
  473. Me.Loaders.Clear()
  474. For Each Loader As LoaderBase In Loaders
  475. If Loader IsNot Nothing Then
  476. Me.Loaders.Add(Loader)
  477. AddHandler Loader.OnStateChangedThread, AddressOf SubTaskStateChanged
  478. Loader.HasOnStateChangedThread = True
  479. End If
  480. Next
  481. InitParent(Nothing)
  482. Me.Name = Name
  483. End Sub
  484. Public Overrides Sub InitParent(Parent As LoaderBase)
  485. Me.Parent = Parent
  486. For Each Loader In Loaders
  487. Loader.InitParent(Me)
  488. Next
  489. End Sub
  490. Public Overrides Sub Start(Optional Input As Object = Nothing, Optional IsForceRestart As Boolean = False)
  491. IsForceRestarting = IsForceRestart
  492. '改变状态
  493. SyncLock LockState
  494. If State = LoadState.Loading Then
  495. Return
  496. Else
  497. State = LoadState.Loading
  498. End If
  499. End SyncLock
  500. '启动加载
  501. Me.Input = Input
  502. If IsForceRestart Then
  503. For Each Loader In Loaders
  504. Loader.State = LoadState.Waiting
  505. Next
  506. End If
  507. RunInThread(AddressOf Update)
  508. End Sub
  509. Public Overrides Sub Cancel()
  510. '改变状态
  511. SyncLock LockState
  512. If State = LoadState.Loading OrElse State = LoadState.Waiting Then
  513. State = LoadState.Canceled
  514. Else
  515. Return
  516. End If
  517. End SyncLock
  518. RunInThread(
  519. Sub()
  520. '中断加载器
  521. For Each Loader In Loaders
  522. Loader.Cancel()
  523. Next
  524. End Sub)
  525. End Sub
  526. Public Overrides Sub Failed(Ex As Exception)
  527. [Error] = Ex '先设置错误再调整状态,防止父加载器获取不到异常
  528. SyncLock LockState
  529. If State >= LoadState.Finished Then Return
  530. State = LoadState.Failed
  531. End SyncLock
  532. For Each Loader In Loaders
  533. Loader.Cancel()
  534. Next
  535. FrmMain.BtnExtraDownload.ShowRefresh()
  536. End Sub
  537. ''' <summary>
  538. ''' 子任务状态变更。
  539. ''' </summary>
  540. Private Sub SubTaskStateChanged(Loader As LoaderBase, NewState As LoadState, OldState As LoadState)
  541. Select Case NewState
  542. Case LoadState.Loading
  543. '开始,啥都不干
  544. Case LoadState.Waiting
  545. '子加载器可能由于外部输入改变而暂时变为 Waiting,之后会立即重新启动
  546. '所以啥都不干就行
  547. Case LoadState.Finished
  548. '正常结束,触发刷新
  549. Update()
  550. Case LoadState.Canceled
  551. '被中断,这个任务也中断
  552. Cancel()
  553. Case LoadState.Failed
  554. '完蛋,出错了
  555. Failed(New Exception(Loader.Name & "失败", Loader.Error))
  556. End Select
  557. End Sub
  558. ''' <summary>
  559. ''' 触发一次更新,以启动新加载器或完成。
  560. ''' </summary>
  561. Private Sub Update()
  562. If State = LoadState.Finished OrElse State = LoadState.Failed OrElse State = LoadState.Canceled Then Return
  563. Dim IsFinished As Boolean = True
  564. Dim Blocked As Boolean = False
  565. Dim Input As Object = Me.Input
  566. For Each Loader In Loaders
  567. Select Case Loader.State
  568. Case LoadState.Finished
  569. '检查 LoaderTask 是否需要重启
  570. If GeneralUtils.IsGenericInstanceOf(Loader, GetType(LoaderTask(Of ,))) Then
  571. If CType(Loader, Object).ShouldStart(If(Input IsNot Nothing AndAlso Loader.GetType.GenericTypeArguments.First Is Input.GetType, Input, Nothing), IgnoreReloadTimeout:=True) Then
  572. Logger.Info($"由于输入条件变更,重启已完成的加载器 {Loader.Name}")
  573. GoTo Restart
  574. End If
  575. '更新下一个加载器的输入
  576. Input = CType(Loader, Object).Output
  577. End If
  578. '如果不让继续启动,且已有加载器正在加载中,就不继续启动
  579. If Loader.Block AndAlso Not IsFinished Then Blocked = True
  580. Case LoadState.Loading
  581. '检查 LoaderTask 是否需要重启
  582. If GeneralUtils.IsGenericInstanceOf(Loader, GetType(LoaderTask(Of ,))) Then
  583. If CType(Loader, Object).ShouldStart(If(Input IsNot Nothing AndAlso Loader.GetType.GenericTypeArguments.First Is Input.GetType, Input, Nothing), IgnoreReloadTimeout:=True) Then
  584. Logger.Warn($"由于输入条件变更,重启进行中的加载器 {Loader.Name}")
  585. GoTo Restart
  586. End If
  587. End If
  588. '已经有正在加载中的了,不需要再启动了
  589. IsFinished = False
  590. Blocked = True
  591. Case Else
  592. Restart:
  593. '未启动,则启动加载器
  594. IsFinished = False
  595. If Blocked Then Continue For
  596. If Input IsNot Nothing Then
  597. '若输入类型与下一个加载器相同才继续
  598. If GeneralUtils.IsGenericInstanceOf(Loader, GetType(LoaderTask(Of ,))) OrElse GeneralUtils.IsGenericInstanceOf(Loader, GetType(LoaderCombo(Of ))) Then
  599. Loader.Start(If(Loader.GetType.GenericTypeArguments.First Is Input.GetType, Input, Nothing), IsForceRestarting)
  600. ElseIf TypeOf Loader Is LoaderWorker Then
  601. Loader.Start(IsForceRestart:=IsForceRestarting)
  602. ElseIf TypeOf Loader Is LoaderDownload Then
  603. Loader.Start(If(TypeOf Input Is List(Of NetFile), Input, Nothing), IsForceRestarting)
  604. Else
  605. Throw New Exception("未知的加载器类型(" & Loader.GetType.Name & ")")
  606. End If
  607. Else
  608. Loader.Start(IsForceRestart:=IsForceRestarting)
  609. End If
  610. '阻止继续
  611. If Loader.Block Then Blocked = True
  612. End Select
  613. Next
  614. If IsFinished Then
  615. '顺利完成,贼棒
  616. RaisePreviewFinish()
  617. State = LoadState.Finished
  618. FrmMain.BtnExtraDownload.ShowRefresh()
  619. End If
  620. End Sub
  621. ''' <summary>
  622. ''' 获得最底层的,应被显示给用户的加载器列表,并追加于 List。
  623. ''' </summary>
  624. Public Shared Sub GetLoaderList(Loader As Object, ByRef List As List(Of LoaderBase), Optional RequireShow As Boolean = True)
  625. For Each SubLoader In Loader.Loaders
  626. If SubLoader.Show OrElse Not RequireShow Then List.Add(SubLoader)
  627. If GeneralUtils.IsGenericInstanceOf(SubLoader, GetType(LoaderCombo(Of ))) Then GetLoaderList(SubLoader, List)
  628. Next
  629. End Sub
  630. ''' <summary>
  631. ''' 获得最底层的,应被显示给用户的加载器列表,并追加于 List。
  632. ''' </summary>
  633. Public Sub GetLoaderList(ByRef List As List(Of LoaderBase), Optional RequireShow As Boolean = True)
  634. GetLoaderList(Me, List, RequireShow)
  635. End Sub
  636. ''' <summary>
  637. ''' 获得最底层的,应被显示给用户的加载器列表。
  638. ''' </summary>
  639. Public Function GetLoaderList(Optional RequireShow As Boolean = True) As List(Of LoaderBase)
  640. Dim List As New List(Of LoaderBase)
  641. GetLoaderList(List, RequireShow)
  642. Return List
  643. End Function
  644. End Class
  645. '任务栏进度条
  646. Public LoaderTaskbar As New ConcurrentList(Of LoaderBase)
  647. Public LoaderTaskbarProgress As Double = 0 '平滑后的进度
  648. Private LoaderTaskbarProgressLast As Shell.TaskbarItemProgressState = Shell.TaskbarItemProgressState.None
  649. Public Sub LoaderTaskbarAdd(Of T)(Loader As LoaderCombo(Of T))
  650. If FrmSpeedLeft IsNot Nothing Then FrmSpeedLeft.TaskRemove(Loader)
  651. LoaderTaskbar.Add(Loader)
  652. Logger.Info($"{Loader.Name} 已加入任务列表")
  653. End Sub
  654. Public Sub LoaderTaskbarProgressRefresh()
  655. Try
  656. Dim NewState As Shell.TaskbarItemProgressState
  657. Dim NewProgress As Double = LoaderTaskbarProgressGet()
  658. '若单个任务已中止,或全部任务已完成,则刷新并移除
  659. For Each Task In LoaderTaskbar
  660. If LoaderTaskbar.All(Function(l) l.State <> LoadState.Loading) OrElse
  661. (Task.State = LoadState.Waiting OrElse Task.State = LoadState.Canceled) Then
  662. FrmSpeedLeft?.TaskRefresh(Task)
  663. LoaderTaskbar.Remove(Task)
  664. Logger.Info($"{Task.Name} 已移出任务列表")
  665. End If
  666. Next
  667. '更新平滑后的进度
  668. If NewProgress <= 0 OrElse NewProgress >= 1 OrElse LoaderTaskbarProgress > NewProgress Then
  669. LoaderTaskbarProgress = NewProgress
  670. Else
  671. LoaderTaskbarProgress = LoaderTaskbarProgress * 0.9 + NewProgress * 0.1
  672. End If
  673. RunInUi(Sub() FrmMain.BtnExtraDownload.Progress = LoaderTaskbarProgress)
  674. '更新任务栏信息
  675. If Not LoaderTaskbar.Any() OrElse LoaderTaskbarProgress = 1 Then
  676. NewState = Shell.TaskbarItemProgressState.None
  677. ElseIf LoaderTaskbarProgress < 0.015 Then
  678. NewState = Shell.TaskbarItemProgressState.Indeterminate
  679. Else
  680. NewState = Shell.TaskbarItemProgressState.Normal
  681. FrmMain.TaskbarItemInfo.ProgressValue = LoaderTaskbarProgress
  682. End If
  683. If LoaderTaskbarProgressLast <> NewState Then
  684. LoaderTaskbarProgressLast = NewState
  685. FrmMain.TaskbarItemInfo.ProgressState = NewState
  686. FrmMain.BtnExtraDownload.ShowRefresh()
  687. End If
  688. Catch ex As Exception
  689. Logger.Error(ex, "刷新任务栏进度显示失败")
  690. End Try
  691. End Sub
  692. Public Function LoaderTaskbarProgressGet() As Double
  693. Try
  694. If Not LoaderTaskbar.Any Then Return 1
  695. Return LoaderTaskbar.Select(Function(l) l.Progress).Average().Clamp(0, 1)
  696. Catch ex As Exception
  697. Logger.Error(ex, "获取任务栏进度出错")
  698. Return 0.5
  699. End Try
  700. End Function
  701. '文件夹刷新类委托
  702. Private LoaderFolderDictionary As New Dictionary(Of LoaderBase, LoaderFolderDictionaryEntry)
  703. Private Structure LoaderFolderDictionaryEntry
  704. Public LastCheckTime As Date?
  705. Public FolderPath As String
  706. Public Overrides Function Equals(obj As Object) As Boolean
  707. If TypeOf obj IsNot LoaderFolderDictionaryEntry Then Return False
  708. Dim entry = DirectCast(obj, LoaderFolderDictionaryEntry)
  709. Return EqualityComparer(Of Date?).Default.Equals(LastCheckTime, entry.LastCheckTime) AndAlso
  710. FolderPath = entry.FolderPath
  711. End Function
  712. End Structure
  713. Public Enum LoaderFolderRunType
  714. RunOnUpdated
  715. ForceRun
  716. UpdateOnly
  717. End Enum
  718. ''' <summary>
  719. ''' 执行以文件夹检测作为输入的加载器。加载器需以文件夹路径为输入值。
  720. ''' 返回是否执行了加载器。
  721. ''' </summary>
  722. ''' <param name="ExtraPath">用于检查文件夹修改的额外路径。该路径不会传入加载器。</param>
  723. Public Function LoaderFolderRun(Loader As LoaderBase, FolderPath As String, Type As LoaderFolderRunType, Optional MaxDepth As Integer = 0, Optional ExtraPath As String = "", Optional WaitForExit As Boolean = False) As Boolean
  724. Dim Value As New LoaderFolderDictionaryEntry With {.FolderPath = FolderPath & ExtraPath, .LastCheckTime = Nothing}
  725. Try
  726. '获取数据
  727. Dim FolderInfo = DirectoryUtils.GetInfo(FolderPath & ExtraPath)
  728. Value.LastCheckTime = If(FolderInfo.Exists, GetActualLastWriteTimeUtc(FolderInfo, MaxDepth), DirectCast(Nothing, Date?))
  729. '如果已经检查过,则跳过
  730. If Type = LoaderFolderRunType.RunOnUpdated AndAlso LoaderFolderDictionary.ContainsKey(Loader) Then
  731. If FolderInfo.Exists Then
  732. If LoaderFolderDictionary(Loader).LastCheckTime IsNot Nothing AndAlso
  733. Value.Equals(LoaderFolderDictionary(Loader)) Then Return False
  734. Else
  735. If LoaderFolderDictionary(Loader).LastCheckTime Is Nothing Then Return False
  736. End If
  737. End If
  738. Catch ex As Exception
  739. Logger.Warn(ex, "文件夹加载器启动检测出错")
  740. End Try
  741. '写入检查数据
  742. LoaderFolderDictionary(Loader) = Value
  743. '开始检查
  744. If Type = LoaderFolderRunType.UpdateOnly Then Return False
  745. If WaitForExit Then
  746. Loader.WaitForExit(FolderPath, IsForceRestart:=True)
  747. Else
  748. Loader.Start(FolderPath, IsForceRestart:=True)
  749. End If
  750. Return True
  751. End Function
  752. Private Function GetActualLastWriteTimeUtc(FolderInfo As DirectoryInfo, MaxDepth As Integer) As Date
  753. Dim Time As Date = FolderInfo.LastWriteTimeUtc
  754. If MaxDepth > 0 Then
  755. For Each Folder In FolderInfo.EnumerateDirectories
  756. Dim FolderTime As Date = GetActualLastWriteTimeUtc(Folder, MaxDepth - 1)
  757. If FolderTime > Time Then Time = FolderTime
  758. Next
  759. End If
  760. Return Time
  761. End Function
  762. End Module